# -*- python -*-

import glob

Import('env libraries')

midi = env.Copy()
midi.Merge ([ libraries['sigc'], libraries['xml'], libraries['pbd'] ])

domain = 'midipp'

midi.Append(DOMAIN=domain,MAJOR=1,MINOR=16,MICRO=1)

sources = Split("""
fd_midiport.cc
fifomidi.cc
midi.cc
midichannel.cc
midicontrollable.cc
midifactory.cc
midimanager.cc
midiparser.cc
midiport.cc
mmc.cc
mtc.cc
port_request.cc
version.cc
""")

sysdep_sources = Split ("""
alsa_sequencer_midiport.cc
coremidi_midiport.cc
""")

if env['SYSMIDI'] == 'CoreMIDI':
   sysdep_src = [ 'coremidi_midiport.cc' ]
   midi.Append (CCFLAGS="-DWITH_COREMIDI")
else:
   sysdep_src = [ 'alsa_sequencer_midiport.cc' ]
   midi.Append (CCFLAGS="-DWITH_ALSA")

midi.Append(CCFLAGS="-D_REENTRANT -D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE")

midi.VersionBuild(['version.cc','midi++/version.h'], 'SConscript')

libmidi = midi.StaticLibrary('midi++', [ sources, sysdep_src ])
Default(libmidi)

env.Alias('tarball', env.Distribute (env['DISTTREE'],
                                     [ 'SConscript' ] + sources + sysdep_sources +
                                     glob.glob('midi++/*.h')))
